pxCreateStaticTriMesh%(vbank*, fbank*, MESH_NBVERTICES%, MESH_NBFACES%)

Параметры

vbank* - указатель на массив вершин
fbank*
MESH_NBVERTICES%
MESH_NBFACES%

Описание

Используется для создания статичных тримешей.

Смотрите так же

Пример

;Пример использования функции
;pxCreateStaticTriMesh

;В данном примере нам понадобятся несколько однотипных тел
Type Px_Cube
    Field body%
    Field mesh%
End Type

Graphics3D 800,600,32,2
SetBuffer BackBuffer()
Global fntArial=LoadFont("Arial",16)

;Создаем свет
light=CreateLight(1)
PositionEntity light,0,50,20

;Создаем камеру
campiv=CreatePivot() ;Камера будет двигаться за кубиком
cam=CreateCamera()
PositionEntity cam,0,7,-15

;Общий план
plane=CreatePlane()
tile1=LoadTexture("media\cell.bmp")
ScaleTexture tile1,5,5
EntityTexture plane,tile1

;Создаем физический мир, устанавливаем гравитацию.
pxCreateWorld(1) ;У нас будет поверхность
pxSetGravity(0,-10,0)

;Загрузим меш для проверки pxCreateStaticTriMesh
level = LoadMesh("media\level.b3d")
PositionMesh level, 0,2,0
CreateTrimeshMesh(level)

tile2=LoadTexture("media\cell.bmp")
ScaleTexture tile2,0.02,0.02
EntityTexture level,tile2

;cube physic
xcubic=PxCreateCube(1,1,1,100)
pxSetPosition(xcubic,0,20,0)

;Создадим множество обектов помех
For i=0 To 250
    ocu.Px_Cube = New Px_Cube
    y# = Rnd (0.2,1)
    x# = Rnd (0.2,1)
    z# = Rnd (0.2,1)
    ocu\mesh=CreateCube ()
    ScaleMesh ocu\mesh,x,y,z
    EntityColor ocu\mesh,Rand(0,255),Rand(0,255),Rand(0,255)
    ocu\body=PxCreateCube(x,y,z, 10)
    pxSetPosition(ocu\body,Rand(-40,40),40,Rand(-40,40))
Next

;Создаем кубик для тестирования статичной поверхности тримеша
cube_body=PxCreateCube(1,1,1, 10)
pxSetPosition cube_body,0,20,0
cube_mesh=CreateCube()
;ScaleMesh cube_mesh,2,2,2
;EntityColor ocu\mesh,255,0,0 ;Цвет красный

While Not(KeyHit(1))

;Применяем силы в зависимости от нажатой клавиши
    If KeyDown(200) pxAddForce(cube_body,0,0,200,0)
    If KeyDown(208) pxAddForce(cube_body,0,0,-200,0)
    If KeyDown(205) pxAddForce(cube_body,200,0,0,0)
    If KeyDown(203) pxAddForce(cube_body,-200,0,0,0)
;пробелом подкиним кубик
    If KeyDown(57) pxAddForce(cube_body,0,500,0,0)

;Раставим все тела по своим местам
    For ocu.Px_Cube = Each Px_Cube
pxSetEntity(ocu\mesh, ocu\body)
    Next
;и наш кубик
    pxSetEntity cube_mesh,cube_body

    PointEntity cam,cube_mesh ; следим за кубиком

;обсчитываем физический мир
    RenderPhysic(60,0)

    UpdateWorld()
    RenderWorld()

    Text 5,25,"Клавиши курсора и пробел - прикладывают силы к кубику"

    Flip
Wend
End

Function CreateTrimeshMesh(mesh%)

    nsurf = CountSurfaces(mesh)
    nvert = 0
    nface=0
    For ns = 1 To nsurf
        Local surf = GetSurface(mesh,ns)
        nface = nface+CountTriangles(surf)
        nvert = nvert +CountVertices(surf)
    Next

    fbank = CreateBank(nface*4*3)
    nf = 0
    vbank = CreateBank(nvert*4*3)
    nv = 0
    For ns = 1 To nsurf
        surf = GetSurface(mesh,ns)
        nfv = CountTriangles(surf)
        For nfc = 0 To nfv -1
            PokeInt fbank,nf*12+0,TriangleVertex(surf,nfc,0)
            PokeInt fbank,nf*12+4,TriangleVertex(surf,nfc,1)
            PokeInt fbank,nf*12+8,TriangleVertex(surf,nfc,2)
            nf=nf+1
        Next

        nvv = CountVertices(surf)
        For nvc = 0 To nvv - 1
            PokeFloat vbank,nv*12+0,VertexX(surf,nvc)
            PokeFloat vbank,nv*12+4,VertexY(surf,nvc)
            PokeFloat vbank,nv*12+8,VertexZ(surf,nvc)
            nv = nv+1
        Next
    Next
; ---------------- Применяем pxCreateStaticTriMesh:
    bbb%=pxCreateStaticTriMesh(vbank, fbank, nvert, nface)
    FreeBank vbank
    FreeBank fbank
    Return bbb%
End Function

К содержанию

Нажмите здесь чтобы увидеть последнюю версию этой странички в режиме online.